Add parameters options to ZStandard encoder

Author: weavejester

src/ring/middleware/content_encoding.clj

@@ -23,8 +23,24 @@
 (defn deflate-encoder ^OutputStream [^OutputStream out]
   (DeflaterOutputStream. out))
 
-(defn zstandard-encoder ^OutputStream [^OutputStream out]
-  (ZstdOutputStream. out))
+(defn zstandard-encoder
+  ([] (zstandard-encoder {}))
+  ([{:keys [chain-log hash-log job-size level long min-match overlap-log
+            search-log strategy target-length window-log workers]}]
+   (fn [^OutputStream out]
+     (-> (ZstdOutputStream. out)
+         (cond-> level         (.setLevel level))
+         (cond-> long          (.setLong long))
+         (cond-> workers       (.setWorkers workers))
+         (cond-> overlap-log   (.setOverlapLog overlap-log))
+         (cond-> job-size      (.setJobSize job-size))
+         (cond-> target-length (.setTargetLength target-length))
+         (cond-> min-match     (.setMinMatch min-match))
+         (cond-> search-log    (.setSearchLog search-log))
+         (cond-> chain-log     (.setChainLog chain-log))
+         (cond-> hash-log      (.setHashLog hash-log))
+         (cond-> window-log    (.setWindowLog window-log))
+         (cond-> strategy      (.setStrategy strategy))))))
 
 (def default-encoder-weights
   {"zstd"     5
@@ -44,7 +60,7 @@
    "deflate"  deflate-encoder
    "gzip"     gzip-encoder
    "identity" identity
-   "zstd"     zstandard-encoder})
+   "zstd"     (zstandard-encoder)})
 
 (def default-status-codes #{200 404 403})
 

test/ring/middleware/content_encoding_test.clj

@@ -84,6 +84,23 @@
     (is (= [40 -75 47 -3 0 88 89 0 0 72 101 108 108 111 32 87 111 114 108 100]
            (vec (.toByteArray out))))))
 
+(deftest zstd-content-encoding-params-test
+  (let [response (ce/content-encoding-response
+                  {:status  200
+                   :headers {"Content-Type" "text/plain; charset=utf-8"}
+                   :body    "aaaaaaaaabbbbbbbbcccccdddeeeaaaabbbbbbbabbab"}
+                  {:headers {"accept-encoding" "zstd"}}
+                  {:encoders {"zstd" (ce/zstandard-encoder {:level 1})}})
+        out      (ByteArrayOutputStream.)]
+    (p/write-body-to-stream (:body response) response out)
+    (is (= {:status 200
+            :headers {"Content-Type"     "text/plain; charset=utf-8"
+                      "Content-Encoding" "zstd"}}
+           (dissoc response :body)))
+    (is (= [40 -75 47 -3 0 72 -19 0 0 -104 97 97 98 99 99 99 99 99 100 100 100
+            101 101 101 97 98 98 97 98 3 0 58 -115 -125 -52 50 -48 6]
+           (vec (.toByteArray out))))))
+
 (deftest different-content-encodings-test
   (let [response (ce/content-encoding-response
                   plain-response