ClassTransformer/settings.gradle at master · MinecraftForge/ClassTransformer · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
pluginManagement {
    includeBuild('classtransformer-gradle')

    repositories {
        gradlePluginPortal()
        maven { url = 'https://maven.minecraftforge.net/' }
        mavenLocal()
    }
}

plugins {
    id 'org.gradle.toolchains.foojay-resolver-convention' version '1.0.0'
}

rootProject.name = 'classtransformer'

includeBuild 'classtransformer-gradle'

//@formatter:off
dependencyResolutionManagement.versionCatalogs.register('libs') {
    version 'gradleutils', '3.4.11'
    plugin 'licenser',       'net.minecraftforge.licenser'    version '1.2.0' // https://plugins.gradle.org/plugin/net.minecraftforge.licenser
    plugin 'gradleutils',    'net.minecraftforge.gradleutils' versionRef 'gradleutils' // https://plugins.gradle.org/plugin/net.minecraftforge.gradleutils
    plugin 'gitversion',     'net.minecraftforge.gitversion'  version '4.0.1' // https://plugins.gradle.org/plugin/net.minecraftforge.gitversion
    plugin 'changelog',      'net.minecraftforge.changelog'   version '3.2.3' // https://plugins.gradle.org/plugin/net.minecraftforge.changelog

    library 'jspecify',  'org.jspecify',       'jspecify'    version '1.0.0'
    library 'jopt',      'net.sf.jopt-simple', 'jopt-simple' version '6.0-alpha-3'
    library 'renamer',   'net.minecraftforge', 'renamer'     version '2.2.8'

    // Transitive dependencies of renamer, we need to add them because renamer does not ship a module-info so java won't actually load them
    version 'asm', '9.9.1'
    library 'asm',         'org.ow2.asm', 'asm'         versionRef 'asm'
    library 'asm-commons', 'org.ow2.asm', 'asm-commons' versionRef 'asm'
    library 'asm-tree',    'org.ow2.asm', 'asm-tree'    versionRef 'asm'
    bundle  'asm', ['asm', 'asm-commons', 'asm-tree']

    // Tests
    version 'junit', '5.10.1'
    library 'junit-api',               'org.junit.jupiter',  'junit-jupiter-api'       versionRef 'junit'
    library 'junit-engine',            'org.junit.jupiter',  'junit-jupiter-engine'    versionRef 'junit'
    library 'junit-platform-launcher', 'org.junit.platform', 'junit-platform-launcher' version '1.10.1'
    bundle  'junit-runtime', ['junit-engine', 'junit-platform-launcher']
}
//@formatter:on

include 'classtransformer-api'
include 'classtransformer-demo'
include 'classtransformer-demo-transformer'